After some investigation I realised that when VCB performed a dump of the VMDK it was correctly dumping the used space. It then dawned on me that when Windows was deleting files from the disk it was actually only deleting the 'pointer' to the data and not the data itself. When VCB was dumping the VMDK it was correctly dumping all blocks of the disk that contained data. I then started looking for a way to clean blocks that were no longer being used but still contained remnants from deleted files. I found a tool called SDelete that writes zero's where the disk contains free space as seen by the Operating System.

I incorporated SDelete into a basic script that also uses Defrag (the Windows utility for defragmenting disks) to tidy up volumes and potentially reduce the size of backups when using VCB.

The script first enumerates all local drives on the VM. For each drive that Windows deems as being a local disk the script then defragments the volume and uses SDelete to zero any free space that the disk may have. The script is written in KiXtart.

Here is the script:

;=====================================================
;=====================================================
;
; ENUMERATE LOCAL DRIVES - DEFRAG & ZERO EMPTY BLOCKS
;
;=====================================================
;=====================================================

;=====================Accept EULA=====================
WriteValue("HKCU\Software\Sysinternals\SDelete", "EulaAccepted", "1", "REG_DWORD")

$Drives = GetObject("winmgmts:").ExecQuery("select Name,DriveType from Win32_LogicalDisk")

For Each $Drive in $Drives

If $Drive.DriveType = 3

SHELL "%comspec% /c " + chr(34) + "defrag.exe " + $Drive.name + " -f" + chr(34)
SHELL "%comspec% /c " + chr(34) + "sdelete.exe -c " + $Drive.name + chr(34)

EndIf

Next

;=====================================================

I use this by placing the folder CleanDisk (download link below) in C:\Program Files. I create a Windows scheduled task to run either KIX32.exe or WKIX32.exe on say a monthly basis.

NOTE: If you have multiple VMs with VMDKs residing on the same physical storage you will probably want to consider staggering the schedules to reduce I/O on the physical disks.

Download the script and necessary files - HERE

I had already used a KiXtart logon script to configure 'Cached Mode' for my Outlook 2003/7 clients by modifying some HKCU registry keys for users - Regkey to enable & disable Outlook 2003 cached mode.

After setting up an Outlook client in VMware Workstation I configured RPC-HTTPS and exported the regkey from the post above (see below for the key.) A fresh install of Outlook with a clean profile and the above key imported revealed that the settings for RPC-HTTPS are stored in the same place as those in the post for enabling cached mode. A combination of changing the values in Outlook and using Regmon allowed me to narrow down exactly what each registry value is used for and the data that each value needs to contain (the data for each registry value is stored as type REG_BINARY which as hexadecimal is unreadable.)

Here is an outline of the registry key and each value with my own description:

HKEY_CURRENT_USER\Software\Microsoft\Windows NT\CurrentVersion\Windows Messaging Subsystem\Profiles\(profilename)\13dbb0c8aa05101a9bb000aa002fc45a

00036623 = Enables 'Connect to Microsoft Exchange using HTTP' as well as 'On fast/slow networks...'
00036627 = Sets the proxy server authentication type (data: 01000000 -> Basic, 02000000 -> NTLM)
001f6622 = Sets the 'proxy server for Exchange' (https://) text box
001f6625 = Sets the 'this principle name' text box

One other registry key I had to set (as per KB820281) to stop clients being prompted for a username/password was:

HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa

lmcompatibilitylevel = 3

I amended my KiXtart login script as follows with the new registry keys, values and their data. The next time users logged on they were connected using RPC over HTTPS:

WRITEVALUE("HKLM\SYSTEM\CurrentControlSet\Control\Lsa", "lmcompatibilitylevel", "3", "REG_DWORD")
WRITEVALUE("HKCU\Software\Microsoft\Windows NT\CurrentVersion\Windows Messaging Subsystem\Profiles\Outlook\13dbb0c8aa05101a9bb000aa002fc45a", "00036623", "2b000000", "REG_BINARY")
WRITEVALUE("HKCU\Software\Microsoft\Windows NT\CurrentVersion\Windows Messaging Subsystem\Profiles\Outlook\13dbb0c8aa05101a9bb000aa002fc45a", "00036627", "02000000", "REG_BINARY")
WRITEVALUE("HKCU\Software\Microsoft\Windows NT\CurrentVersion\Windows Messaging Subsystem\Profiles\Outlook\13dbb0c8aa05101a9bb000aa002fc45a", "001f6622", "xxxx", "REG_BINARY")
WRITEVALUE("HKCU\Software\Microsoft\Windows NT\CurrentVersion\Windows Messaging Subsystem\Profiles\Outlook\13dbb0c8aa05101a9bb000aa002fc45a", "001f6625", "xxxx", "REG_BINARY")

You can verify that users are connected using RPC over HTTPS by holding down CTRL and SHIFT on the keyboard and using the mouse to right-click the system tray icon. Click on the 'Connection Status...' option and you will see that the 'Conn' column displays multiple connections of type: HTTPS.

The following script uses two other applications:

BMail - A command line SMTP mailing tool
Uptime - Allows you to estimate Server availability

Full credit to Craig Peacock for BMail.

Here is the script:

;===============================================
;===============================================
;
; Clear Existing Uptime Report
;
;===============================================
;===============================================

IF EXIST ("Report")
DEL "Report\*.txt"
ENDIF

;===============================================
;===============================================
;
; Produce Uptime Report
;
;===============================================
;===============================================

;Convert YYYY/MM/DD to DD-MM-YYYY
$temp = @DATE
$todaysdate = SUBSTR($temp, 9, 2)
$todaysdate = $todaysdate + "-" + SUBSTR($temp, 6, 2)
$todaysdate = $todaysdate + "-" + SUBSTR($temp, 1, 4)

;Array containing server names
Dim $ComputerNames[5]
$ComputerNames[0] = "Server01"
$ComputerNames[1] = "Server02"
$ComputerNames[2] = "Server03"
$ComputerNames[3] = "Server04"
$ComputerNames[4] = "Server05"

;If Report directory doesn't exist then create it
IF NOT EXIST ("Report")
MD "Report"
ENDIF

;Output uptime report for all computers in the array
For Each $Element In $ComputerNames

IF $Element = ""
GoTo "Email"
ENDIF

shell "%comspec% /c " + chr(34) + "Uptime.exe" + " " + $Element + " " + chr(34) + " /s /p:31 >> Report\$todaysdate-UptimeReport.txt"
shell "%comspec% /c echo. >> Report\$todaysdate-UptimeReport.txt"
shell "%comspec% /c echo. >> Report\$todaysdate-UptimeReport.txt"
shell "%comspec% /c echo ******************************************************************************** >> Report\$todaysdate-UptimeReport.txt"
shell "%comspec% /c echo ******************************************************************************** >> Report\$todaysdate-UptimeReport.txt"
shell "%comspec% /c echo ******************************************************************************** >> Report\$todaysdate-UptimeReport.txt"
shell "%comspec% /c echo. >> Report\$todaysdate-UptimeReport.txt"
shell "%comspec% /c echo. >> Report\$todaysdate-UptimeReport.txt"

Next

:Email
;===============================================
;===============================================
;
; Email Uptime Report
;
;===============================================
;===============================================

$emailserver = "someemailserver"
$toaddress = "james" + chr(64) + "somedomain.com"
$fromaddress = "uptime" + chr(64) + "somedomain.com"
$subject = "Uptime Report For all London Servers"

;Form email command
$emailcommand = "bmail -s " + $emailserver + " -t " + $toaddress + " -f " + $fromaddress + " -h -a " + chr(34) + $subject + chr(34) + " -m " + "Report\" + $todaysdate + "-UptimeReport.txt" + " -c"

RUN ($emailcommand)

;===============================================

The script works by generating a file that contains the results of uptime.exe for each server specified. The contents of the file are then emailed using bmail.

This script obviously requires a few variables to be modified to get it to work in another environment. The following will need to be altered:

Dim $ComputerNames[5] - you will need to change the numeric value to the number of servers you want to generate a report for

NOTE: the example above is for 5 servers. If you wanted to monitor 4 servers then you will need to modify the array to change the number of elements to 4. So your array would look like (the last line has been removed):

$ComputerNames[0] = "Server01"
$ComputerNames[1] = "Server02"
$ComputerNames[2] = "Server03"
$ComputerNames[3] = "Server04"

$ComputerNames[0] = "Server01" - you need to change Server01 to the server you want to generate a report for
$emailserver - the name of your email server (the server running this script must be allowed to relay through it)
$toaddress - the address you want the email alert to go to
$fromaddress - the (spoof) address you want the email to appear to come from
$subject - the subject line of the email

I use a scheduled task on a Windows Server 2003 to run this script once a month. It generates a report for the last 31 days of uptime for each server in the array and then emails me the report.

NOTE: you can change 31 day period that the script gathers uptime information for by modifying /p:31 on the following line:

(31 represents the number of days in the past to gather uptime statistics for)

shell "%comspec% /c " + chr(34) + "Uptime.exe" + " " + $Element + " " + chr(34) + " /s /p:31 >> Report\$todaysdate-UptimeReport.txt"

To use this:

1) Save the above script as kixtart.kix in a directory containing the kixtart application
2) Save bmail.exe and uptime.exe (available from the links above) in the same directory
3) Modify variables as appropriate
4) Make sure that the server running the script can relay email through your email server
5) Test by running the script manually and/or create the scheduled task

Alternatively, download the above script and necessary files - HERE

The end result is an email with a breakdown of uptime availability for each server including any dates and times where necessary.

Rather than spending money on the software and licensing required to upgrade both Oracle and the Operating System (as it's being replaced anyway) the company made a decision to live with the issue for the time being. I decided to write a KiXtart script to monitor the website and let me know of any issues it may incur.

The following script uses two other applications:

BMail - A command line SMTP mailing tool
WebResult - A command line URL result code tool

Full credit to Craig Peacock for BMail and John Mueller for WebResult.

Here is the script:

;===============================================
;===============================================
;
; Remove temp files
;
;===============================================
;===============================================

IF EXIST ("result.txt")
DEL ("result.txt")
ENDIF

IF EXIST ("status.txt")
DEL ("status.txt")
ENDIF

;===============================================
;===============================================
;
; Check/record http status in result.txt
;
;===============================================
;===============================================

$website = "http://www.jjclements.co.uk"

SHELL "%comspec% /c " + chr(34) + "webresult.exe " + $website + chr(34) + " >> result.txt"

;===============================================
;===============================================
;
; Open result.txt and read into variable
;
;===============================================
;===============================================

getfilecontents("result.txt")

;===============================================
;===============================================
;
; Explode variable into array
;
;===============================================
;===============================================

$myarray = SPLIT ($result, " ", -1)

;===============================================
;===============================================
;
; Declare global variable to store desc
;
;===============================================
;===============================================

$errordesc = ""

;===============================================
;===============================================
;
; Check each array element against codes
;
;===============================================
;===============================================

$element = $myarray[1]
SELECT

CASE $element = "0"
$errordesc = "The current status is: Error " + $element + " - Website Unavailable"

CASE $element = "400"
$errordesc = "The current status is: Error " + $element + " - Bad Request"

CASE $element = "403"
$errordesc = "The current status is: Error " + $element + " - Forbidden"

CASE $element = "404"
$errordesc = "The current status is: Error " + $element + " - Not Found"

CASE $element = "405"
$errordesc = "The current status is: Error " + $element + " - Method Not Allowed"

CASE $element = "406"
$errordesc = "The current status is: Error " + $element + " - Not Acceptable"

CASE $element = "408"
$errordesc = "The current status is: Error " + $element + " - Request Timeout"

CASE $element = "409"
$errordesc = "The current status is: Error " + $element + " - Conflict"

CASE $element = "410"
$errordesc = "The current status is: Error " + $element + " - Gone"

CASE $element = "500"
$errordesc = "The current status is: Error " + $element + " - Internal Server Error"

CASE $element = "501"
$errordesc = "The current status is: Error " + $element + " - Not Implemented"

CASE $element = "502"
$errordesc = "The current status is: Error " + $element + " - Bad Gateway"

CASE $element = "503"
$errordesc = "The current status is: Error " + $element + " - Internal Server Error"

CASE $element = "504"
$errordesc = "The current status is: Error " + $element + " - Gateway Timeout"

CASE $element = "505"
$errordesc = "The current status is: Error " + $element + " - HTTP Version not supported"

CASE 1
EXIT

ENDSELECT

;===============================================
;===============================================
;
; Threshold - Times to retry + interval
;
;===============================================
;===============================================

$numberofretries = "2"
$latencyseconds = "10"

IF $numberofretries > "0"

DO

SLEEP $latencyseconds

IF EXIST ("result.txt")
DEL ("result.txt")
ENDIF

SHELL "%comspec% /c " + chr(34) + "webresult.exe " + $website + chr(34) + " >> result.txt"

getfilecontents("result.txt")

$mytemparray = SPLIT ($result, " ", -1)

$tempelement = $mytemparray[1]

IF NOT $element = $tempelement
EXIT
ENDIF

$currentretry = $currentretry + 1

UNTIL $numberofretries = $currentretry

ENDIF

;===============================================
;===============================================
;
; Email Server Status
;
;===============================================
;===============================================

$emailserver = "someemailserver"
$toaddress = "james" + chr(64) + "somedomain.com"
$fromaddress = "serverfailure" + chr(64) + "somedomain.com"
$subject = "Server Issue"

;Form email body
shell "%comspec% /c echo. >> status.txt"
shell "%comspec% /c echo. >> status.txt"
shell "%comspec% /c echo WebServer is currently offline >> status.txt"
shell "%comspec% /c echo. >> status.txt"
shell "%comspec% /c echo " + $errordesc + " >> status.txt"
shell "%comspec% /c echo. >> status.txt"
shell "%comspec% /c echo Please restart the WebServer application to ensure SLAs are adhered to! >> status.txt"

;Form email command
$emailcommand = "bmail -s " + $emailserver + " -t " + $toaddress + " -f " + $fromaddress + " -h -a " + chr(34) + $subject + chr(34) + " -m " + "status.txt" + " -c"

SHELL ($emailcommand)

;=======================================
; Get File Contents
;=======================================

Function getfilecontents($filesource)

OPEN (1, "$filesource")
$result = READLINE (1)
CLOSE (1)

EndFunction

;=======================================

This script obviously requires a few variables to be modified to get it to work in another environment. The following will need to be altered:

$website - you will need to enter your own website you want to monitor here (you must use http://)
$numberofretries - the number of times the script will test the website before emailing an error
$latencyseconds - the time in seconds before each retry (if $numberofretries is NOT set to 0)
$emailserver - the name of your email server (the server running this script must be allowed to relay through it)
$toaddress - the address you want the email alert to go to
$fromaddress - the (spoof) address you want the email to appear to come from
$subject - the subject line of the email

The only other thing you may want to change is the message contained within the email (underneath ';Form email body'). I have a few instances of this script monitoring different servers so I have customised the email body for each server to inform me of the server name and IP address etc.

As mentioned the script makes use of a threshold although it isn't used if you set $numberofretries = "0". The threshold sets the number of times to try the website before sending an email. You can also set the delay between each retry (in seconds) by setting a value for $latencyseconds.

I use a scheduled task on a Windows Server 2003 to run this script every 5 minutes. When there is a problem with the web application I am alerted to it and can respond as necessary. One thing to be aware of, if you set your scheduled task to run every 5 minutes but you set the script to retry say 3 times with a latency of 120 seconds (total 360 seconds - 6 minutes) then the scheduled task will try to run again before the script has finished causing problems.

To use this:

1) Save the above script as kixtart.kix in a directory containing the kixtart application
2) Save webresult.exe and bmail.exe (available from the links above) in the same directory
3) Modify variables as appropriate
4) Make sure that the server running the script can relay email through your email server
5) Test by running the script manually and/or create the scheduled task

Alternatively, download the above script and necessary files - HERE

The end result is an email that tells you the exact http error code and description when your web application becomes unavailable and meets any threshold that may be set.

Here is the logon screen before the registry key has been added:

Here is what happens if a user selects the "Log on using dial-up connection" checkbox before logging on:

Setting the following registry key will disable the checkbox, disabling all users from using the dial-up connection feature:

HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon

you will need to manually create a new string value (REG_SZ) called RasDisable. Set the value's data to 1.

Here is the final result:

And finally here is what I wrote to add the regkey to all computers using a KiXtart startup script through Group Policy:

;===============================================
;===============================================
;
; DISABLE LOGON USING DIAL-UP CONNECTION
;
;===============================================
;===============================================

IF READVALUE("HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon", "RasDisable") <>"1"
WRITEVALUE("HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon", "RasDisable", "1", "REG_SZ")
ENDIF

NOTE: I've noticed that the quote marks are not displayed properly on this page. Here is the KiXtart script in its intended form:

Download Here

When you install MSSQL on a server, the ‘PATH’ environment variable is changed to include the location of the SQL tools (the default being: C:\Program Files\Microsoft SQL Server\80\Tools\BINN). The script runs without needing to know where osql.exe is installed and passes it switches to initiate a complete backup. Once the backup has completed SQL Server Enterprise Manager reflects the new date and time of the last backup taken as though you have used its own SQL Server Backup utility.

The script executes osql.exe with 2 switches, -E and -Q.

-E = Uses windows authentication (the credentials of the currently logged on user OR if using a scheduled task to run the script the credentials specified when initially creating the task)

-Q = Runs the SQL statement and exits osql.exe

Here is the script, you will only need to modify 2 variables ($databasename and $backuplocation) to set the name of the database you want to backup and the location of where you want the backup saved:

;===============================================
;===============================================
;
; Backup MSSQL Database
;
;===============================================
;===============================================

;Convert YYYY/MM/DD to DD-MM-YYYY
$temp = @DATE
$todaysdate = SUBSTR($temp, 9, 2)
$todaysdate = $todaysdate + "-" + SUBSTR($temp, 6, 2)
$todaysdate = $todaysdate + "-" + SUBSTR($temp, 1, 4)

;Set Backup Parameters
$databasename = "MyDatabase"
$backuplocation = "c:\MSSQL Backups\"

;If backup directory doesn't exist then create it
IF NOT EXIST ($backuplocation)
MD ($backuplocation)
ENDIF

;Delete existing backup if it exists
IF EXIST ($backuplocation)
DEL ($backuplocation + "*.*")
ENDIF

;Form Backup command
$backupcommand = "osql -E -Q " + chr(34) + "BACKUP DATABASE " + $databasename + " TO DISK = '" + $backuplocation + $databasename + "-" + $todaysdate + ".bak" + "'" + chr(34)

SHELL ($backupcommand)

;===============================================

If you ever wanted to restore from this backup you could use the command line to restore it again. Here is an example restore command (remove the brackets):

osql -E -Q "RESTORE DATABASE (databasename) FROM DISK = 'c:\MSSQL Backups\(mydatabasebackup.bak)'"

You can obviously also use SQL Server Enterprise Managers own SQL Server Backup utility to restore the database as well.

The organisation I work for has an application that requires each user’s telephone extension. So I use this script to retrieve the user’s telephone extension (from the Active Directory Telephone number attribute) during logon. It then writes that value to the appropriate registry key required by the application. This way all I have to remember to do when creating a new user or changing the users telephone is to set/change the 'Telephone number' attribute on the users account using the Active Directory Users and Computers MMC.

Here's the script:

;Retrieve Active Directory user information
$objSysInfo = CreateObject("ADSystemInfo")
$strUser = $objSysInfo.UserName
$objUser = GetObject("LDAP://" + $strUser)

$strPhone = $objUser.telephoneNumber
$strName = $objUser.FullName
$strTitle = $objUser.Title
$strMail = $objUser.mail
$strDepartment = $objUser.Department
$strCompany = $objUser.Company
$strStreet = $objUser.StreetAddress
$strPostalCode = $objUser.PostalCode
$strCity = $objUser.L
$strCountry = $objUser.Co
$strPhone = $objUser.telephoneNumber
$strFax = $objUser.FacsimileTelephoneNumber
$strMobile = $objUser.Mobile
$strWeb = $objUser.wWWHomePage

As an example, here is how I could now write an Active Directory attribute to the registry, checking for some form of its existence before hand:

IF NOT $strPhone = ""
WRITEVALUE("HKCU\Software\MyTelephoneApp", "TelephoneNo", $strPhone, "REG_SZ")
ENDIF